<Ler dados de um ficheiro TXT ou MDB ⁄ >

7039

2006-10-09

mySnippets asp

Download

Bookmark This

Para que serve guardar dados se não os analisarmos posteriormente? Sejam eles de que tipo forem, texto, numéricos, etc, etc. Num snippet anterior tinha exemplificado uma possivel forma para de Guardar dados num ficheiro TXT ou MDB, agora irei tentar exemplificar uma possivel maneira de mostrar os dados inseridos pelo cliente (que tanto poderá servir para nós como poderá eventualmente ser mostrado ao cliente, caso assim seja necessário).

Comecemos então por ver a leitura do ficheiro em MDB (terei como base a informação do outro snippet, como tal poderão dar uma vista de olhos e ver como estava estruturada a base de dados).

<%
 
sub showMDB(file)
  Dim adoCon 'conecção à base de dados
  Dim rsComentarios 'recorset
  Dim strSQL
  Dim str 'vai armazenar o conteúdo do ficheiro para posteriormente ser enviado para o output
 
  Set adoCon = Server.CreateObject("ADODB.Connection") 'criar a ligação do tipo ADODB
  adoCon.Open "DRIVER={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath(file)
  Set rsComentarios = Server.CreateObject("ADODB.Recordset") 'criar o recordset
  strSQL = "SELECT nome, opiniao,aspectos,pontos FROM dados_comentarios;" 'instrução sql
  rsComentarios.Open strSQL, adoCon
  Do While not rsComentarios.EOF 'enquanto não chegarmos ao fim da tabela ...
    str = str & "<p align='left'>"
    str = str & "<br>Nome: " & rsComentarios("nome")
    str = str & "<br>Opinião: " & rsComentarios("opiniao")
    str = str & "<br>Aspectos Positivos: " & rsComentarios("aspectos")
    str = str & "<br>Pontos a Melhorar: " & rsComentarios("pontos")
    str = str & "</p>"
    rsComentarios.MoveNext 'já temos a informação deste registo, vamos passar ao próximo
  Loop	
 
  Response.Write(str) 'enviar para o output a informação
 
  rsComentarios.Close
  Set rsComentarios = Nothing
  Set adoCon = Nothing
end sub
 
%>

A leitura do ficheiro em TXT será mais fácil e não tão extensa como a leitura no formato MDB, de salientar apenas uma diferença, se repararam no método de ler do MDB, é adicionada informação para que o cliente saiba a que responde a campo (Nome, Aspectos Positivos, etc); ao passo que no TXT (criado no outro snippet) guardavamos logo a descrição da informação, como tal neste método só teremos que nos preocupar com o envio do conteúdo do ficheiro para o output, tal funcionamento poderá nem sempre funcionar correctamente, daí que por vezes teremos de usar uma maneira diferente de ler o conteúdo do ficheiro e enviá-lo para o ecrã.

<%
 
sub showTXT(file)
  Dim str 'vai armazenar o conteúdo do ficheiro para posteriormente ser enviado para o output
 
  Set fs=Server.CreateObject("Scripting.FileSystemObject")
  if not fs.FileExists(Server.MapPath(file)) then
    str= "ainda não existem comentários"
  else
    Set f=fs.OpenTextFile(Server.MapPath(file), 1)
    str = str & (replace(f.ReadAll,VbCrLf,"<br>")) 'substituir \n\r por <br> (sensivelmente igual ao nl2br do php)
    f.Close
  end if 
 
  Response.Write (str) 'enviar para o output a informação
 
  Set f=Nothing
  Set fs=Nothing
end sub
 
%>

O html neste snippet será extremamente simples visto não ser este o objectivo do snippet, mas posso recomendar que por exemplo utilizem CSS em vez de estarem a definir os atributos das tags como poderão ver facilmente no meu exemplo, basicamente, sempre que possivel recorram ao uso de css.

<html>
<head>
<title>Questionário - Comentários</title>
</head>
<body bgcolor="white" text="black">
<font face="Tahoma" size="2">
<p align="center"><b>Respostas ao nosso Questionário</b></p>
<%
showMDB "pathToFile/file.mdb"
showTXT "pathToFile/file.txt"
%>
</font>
</body>
</html>

Qualquer erro/ dúvida é só dizer!

7039

2006-10-09

mySnippets asp

Download

Bookmark This